/home/carolina/workspace/spvolren_cpu/volumeShaders/isosurface_clipped_sm3.fp

Vá para a documentação deste arquivo.

!!ARBfp1.0
OPTION NV_fragment_program2;

# Copyright (c) 2005  Institute for Visualization and Interactive
# Systems, University of Stuttgart, Germany
#
# This source code is distributed as part of the single-pass volume
# rendering project. Details about this project can be found on the
# project web page at http://www.vis.uni-stuttgart.de/eng/research/
# fields/current/spvolren. This file may be distributed, modified,
# and used free of charge as long as this copyright notice is
# included in its original form. Commercial use is strictly
# prohibited.
#
# Filename: isosurface_clipped_sm3.fp

#! VOLUME = 0
#! BACKGROUND = 1
#! CLIPVOLUME = 2

# r = step
# g = gradient scale
# b = gradient offset
# a = z-value of background plane
PARAM params = program.local[0];

# r = texture coordinate scale
# g = number of iterations
# b = isovalue of isosurface
PARAM params2 = program.local[1];

# r = scattering scale
# g = isovalue of clipping isosurface
PARAM params3 = program.local[4];

PARAM center = program.local[2];
PARAM texMax = program.local[3];

PARAM scaleFactors = program.local[5];

PARAM isColor1 = {0.0, .5, 0.0, 1.0};
PARAM isColor2 = {0.0, 0.0, .5, 1.0};

TEMP geomDir;
TEMP geomPos;
TEMP lightVec;
TEMP texCoord;
TEMP prevPos;
TEMP texblen;
TEMP diffVec;
TEMP halfway;
TEMP eyeVec;
TEMP intens;
TEMP camera;
TEMP normal;
TEMP weight;
TEMP temp1;
TEMP temp2;
TEMP temp;
TEMP grad;
TEMP pos;
TEMP src;
TEMP dst;
TEMP dir;
TEMP tex;
TEMP scalActInner;
TEMP scalPreInner;
TEMP scalActOuter;
TEMP scalPreOuter;

# Compute the ray's starting point
MOV geomPos, fragment.texcoord[0];
MUL pos, geomPos, scaleFactors;
MOV pos.a, 0.0;

# Compute the camera position by translating the origin to the center of the
# volume
MOV camera, state.matrix.modelview.invtrans.row[3];

# Compute the ray direction
SUB geomDir, geomPos, camera;

# Normalize the direction
DP3 geomDir.w, geomDir, geomDir;
RSQ geomDir.w, geomDir.w;
MUL geomDir, geomDir, geomDir.w;
MOV geomDir.w, 0.0;

MUL dir, geomDir, scaleFactors;

# Initialize the 'previous' intensity
TXL intens, pos, texture[0], 3D;
MOV scalPreOuter, intens.a;

MAD pos, dir, params.r, pos;

# Initialize texture corrdinates
# texcood.a inherits level of detail
MOV texCoord, 0.0;

# Initialize destination color
MOV dst, 0.0;

#REP params2.g;

        REP params2.g;
                # Lookup scalar and gradient
                MOV texCoord.rgb, pos;
                TXL tex, texCoord, texture[0], 3D;

                MOV scalActOuter, tex.a;

                # Move one step forward
                MAD pos, dir, params.r, pos;

                # Isosurface if differences with past and present
                # scalar values and isovalue have different signs 
                MOV intens.r, scalActOuter;
                MOV intens.g, scalPreOuter;
                SUB temp.rg, intens, params2.b;
                MULC temp, temp.r, temp.g;
                IF LE.x;
                        # Isosurface found
                        MOV src, isColor1;

                        # Get scalar value from actual position
                        MAD pos, -dir, params.r, pos;
                        TXL scalActInner, pos, texture[0], 3D;
                        
                        # Get scalar value from previous position
                        MAD prevPos, -dir, params.r, pos;
                        TXL scalPreInner, prevPos, texture[0], 3D;

                        SUB temp.r, params2.b, scalPreInner.a;
                        SUBC temp.g, scalActInner.a, scalPreInner.a;

                        # Determine isosurface color
                        MOV src (LT.g), isColor2;

                        # Perform linear interpolation to increase accuracy
                        DIV_SAT temp.b, temp.r, temp.g;
                        LRP pos, temp.b, pos, prevPos;

                        TXL tex, pos, texture[2], 3D;
                        SUBC tex.x, tex.x, params3.g;
                        IF GE.x;
                                # Determine gradient at corrected position (same as above)
                                MOV texCoord.rgb, pos;
                                TXL tex, pos, texture[0], 3D;
                                MOV grad.rgb, tex;

                                # Determine scale factor for gradient
                                SNE temp.rgb, grad, 0.0;
                                DP3_SAT temp.r, temp, 1.0;

                                # Reconstruct the gradient
                                MAD_SSAT grad.rgb, tex, 2.0, -1.0;
                                NRM_SSAT grad.rgb, grad;

                                # Set gradient to zero if it was zero
                                MUL grad.rgb, grad, temp.r;

                                # Re-orient the gradient to get a
                                # correct surface normal
                                MOV temp, 0.0;
                                DP3 temp.r, -geomDir, grad;
                                NRM temp, temp;
                                MUL grad.rgb, grad, temp.r;

                                # Perform the lighting calculation (yes, we know LIT!)

                                # Ambient term
                                MUL dst, state.light[0].ambient, src;

                                # Diffuse term
                                SUB lightVec.rgb, state.light[0].position, geomPos;
                                MOV lightVec.a, 0.0;
                                NRM lightVec, lightVec;
                                DP3_SAT temp.a, lightVec, grad;
                                MUL temp, src, temp.a;
                                MAD dst, state.light[0].diffuse, temp, dst;

                                # Specular term
                                # First calculate halfway vector
                                ADD halfway, lightVec, -geomDir;
                                MOV halfway.a, 0.0;
                                NRM halfway, halfway;
                                # Specular Lighting
                                SUB eyeVec.rgb, camera, geomPos;
                                MOV eyeVec.a, 0.0;
                                NRM eyeVec, eyeVec;
                                DP3_SAT temp.a, halfway, grad;
                                POW temp.a, temp.a, 10.0;
                                MAD dst, state.light[0].specular, temp.a, dst;
                                # Isofurfaces are opaque
                                MOV dst.a, 1.0;

                                # Everything is done, jump out of loop
                                MOVC temp.x, 0.0;
                                BRK (EQ.x);
                        ENDIF;
                ENDIF;

                MOV scalPreOuter, scalActOuter;

                # Set values to zero if outside volume
                SGE temp1, pos, 0.0;
                SLE temp2, pos, texMax;
                DP3 weight.r, temp1, temp2;
                SEQC weight.r, weight.r, 3.0;

                # Already outside volume, skip the rest
                BRK (EQ.x);

        ENDREP;

        #BRK (EQ.x);

#ENDREP;

# Compute the normal of the background plane (this is just the negative view
# direction which initially is (0, 0, -1))
MOV normal, state.matrix.modelview.row[2];

# Compute the plane constant (we want the plane to be located in the volume
# center)
DP3 temp1.r, normal, center;

# Move the plane behind the volume: d' = <n,(x - l n)> = <n, x> - l <n, n>;
# l = 0.71 is chosen since it is greater than half the cube diagonal 
DP3 temp1.g, normal, normal;
MAD temp1.r, temp1.g, -.71, temp1.r;

# Compute ray parameter
DP3 temp1.g, normal, geomPos;
SUB temp1.g, temp1.r, temp1.g;
DP3 temp1.b, normal, geomDir;
DIV temp.r, temp1.g, temp1.b;

# Compute ray/plane intersection
MAD temp.rgb, temp.r, geomDir, geomPos;

# Compute the difference vector
SUB diffVec, temp, center;

# Compute the texture coordinates
DP3 temp.r, diffVec, state.matrix.modelview.row[0];
DP3 temp.g, diffVec, state.matrix.modelview.row[1];
MUL temp.rg, temp, params2.r;

# Center background image
ADD temp.rg, temp, .5;

# Look up the texel value
TEX temp.rgb, temp, texture[1], 2D;
MOV temp.a, 1.0;

# Blend the background pixel
SUB texblen, 1.0, dst.a;
MAD dst, temp, texblen.x, dst;

# Write the output color
MOV result.color, dst;

END

---