/home/carolina/workspace/spvolren_cpu/volumeShaders/volume_refraction_sm3.fp

Vá para a documentação deste arquivo.

!!ARBfp1.0
OPTION NV_fragment_program2;

# Copyright (c) 2005  Institute for Visualization and Interactive
# Systems, University of Stuttgart, Germany
#
# This source code is distributed as part of the single-pass volume
# rendering project. Details about this project can be found on the
# project web page at http://www.vis.uni-stuttgart.de/eng/research/
# fields/current/spvolren. This file may be distributed, modified,
# and used free of charge as long as this copyright notice is
# included in its original form. Commercial use is strictly
# prohibited.
#
# Filename: volume_refraction_sm3.fp

#! VOLUME = 0
#! TRANSFERFUNCTION = 1
#! OPTICALDENSITY = 2
#! BACKGROUND = 3

# r = step
# g = gradient scale
# b = gradient offset
# a = z-value of background plane
PARAM params = program.local[0];

# r = texture coordinate scale
# g = number of iterations
# b = isovalue of isosurface
PARAM params2 = program.local[1];
PARAM center = program.local[2];
PARAM texMax = program.local[3];

PARAM scaleFactors = program.local[5];
PARAM scaleFactorsInv = program.local[6];

TEMP geomDir;
TEMP geomPos;
TEMP lightVec;
TEMP texCoord;
TEMP texblen;
TEMP diffVec;
TEMP eyeVec;
TEMP intens;
TEMP camera;
TEMP normal;
TEMP weight;
TEMP temp1;
TEMP temp2;
TEMP temp;
TEMP grad;
TEMP sign;
TEMP pos;
TEMP src;
TEMP dst;
TEMP dir;
TEMP tex;

# Compute the ray's starting point
MOV geomPos, fragment.texcoord[0];
MUL pos, geomPos, scaleFactors;
MOV pos.a, 0.0;

MOV texCoord, 0.0;

# Compute the camera position by translating the origin to the center of the
# volume
MOV camera, state.matrix.modelview.invtrans.row[3];

# Compute the ray direction
SUB geomDir, geomPos, camera;

# Normalize the direction
DP3 geomDir.w, geomDir, geomDir;
RSQ geomDir.w, geomDir.w;
MUL geomDir, geomDir, geomDir.w;
MOV geomDir.w, 0.0;

MUL dir, geomDir, scaleFactors;

# Initialize the optical density
TXL intens, pos, texture[0], 3D;
MOV intens.g, intens.a;
MOV texCoord.rgb, intens.a;
TXL intens.r, texCoord, texture[2], 1D;
MOV intens.a, intens.r;
# Scale the optical density (keep in sync with initialization below)
MUL intens.a, intens.a, params.g;
ADD intens.a, intens.a, params.b;

MOV sign, 0.0;

REP params2.g;
        REP params2.g;
                # Determine scalar value and gradient
                TXL tex, pos, texture[0], 3D;
                MOV intens.r, tex.a;
                MOV grad.rgb, tex;

                # Determine scale factor for gradient
                SNE temp.rgb, grad, 0.0;
                DP3_SAT temp.r, temp, 1.0;

                # Reconstruct the gradient
                MAD_SSAT grad.rgb, tex, 2.0, -1.0;
                NRM_SSAT grad.rgb, grad;

                # Set gradient to zero if it was zero
                MUL grad.rgb, grad, temp.r;

                # Determine optical density
                MOV texCoord.rgb, intens.r;
                TXL intens.b, texCoord, texture[2], 1D;

                # Scale the optical density (keep in sync with initialization above)
                MUL intens.b, intens.b, params.g;
                ADD intens.b, intens.b, params.b;

                # The direction vector must be in world-space and normalized
                MUL temp1, dir, scaleFactorsInv;
                NRM temp1, temp1;

                # Determine case
                DP3 sign.r, temp1, grad;
                NRM_SSAT sign, sign;
                DP3 temp.r, -temp1, grad;

                # temp.rga <- shift vector perpendicular to surface normal (a)
                MAD temp.rgb, temp.r, grad, temp1;

                # temp.a <- ratio of optical densities (n1/n2)
                DIV temp.a, intens.a, intens.b;

                # dir.rgb <- (n1/n2) * a
                MUL temp1.rgb, temp, temp.a;
                DP3_SAT temp.r, temp1, temp1;
                SUB_SAT temp.r, 1.0, temp.r;
                POW_SAT temp.r, temp.r, 0.5;
                MUL temp.r, temp.r, sign.r;
                MAD temp1.rgb, temp.r, grad, temp1;
                NRM temp1.rgb, temp1;
                MUL dir, temp1, scaleFactors;

                # Move one step forward
                MAD pos.rgb, dir, params.r, pos;

                # Set values to zero if outside volume
                SGE temp1, pos, 0.0;
                SLE temp2, pos, texMax;
                DP3 weight.r, temp1, temp2;
                SEQC weight.r, weight.r, 3.0;
                # Already outside volume, skip the rest
                BRK (EQ.x);
                
                MOV texCoord.rg, intens;
                TXL src, texCoord, texture[1], 2D;
                SUBC texblen, 1.0, dst.a;

                # Early ray termination (XXX DOES NOT WORK!)
                #BRK (EQ.x);

                MAD dst, src, texblen.x, dst;
                MOV intens.g, intens.r;

                # Copy optical density
                MOV intens.a, intens.b;
        ENDREP;
        BRK (EQ.x);
ENDREP;

MUL geomPos, pos, scaleFactorsInv;
MUL geomDir, dir, scaleFactorsInv;

# Compute the normal of the background plane (this is just the negative view
# direction which initially is (0, 0, -1))
MOV normal, state.matrix.modelview.row[2];

# Compute the plane constant (we want the plane to be located in the volume
# center)
DP3 temp1.r, normal, center;

# Move the plane behind the volume: d' = <n,(x - l n)> = <n, x> - l <n, n>;
# l = 0.71 is chosen since it is greater than half the cube diagonal 
DP3 temp1.g, normal, normal;
MAD temp1.r, temp1.g, -.71, temp1.r;

# Compute ray parameter
DP3 temp1.g, normal, geomPos;
SUB temp1.g, temp1.r, temp1.g;
DP3 temp1.b, normal, geomDir;
DIV temp.r, temp1.g, temp1.b;

# Compute ray/plane intersection
MAD temp.rgb, temp.r, geomDir, geomPos;

# Compute the difference vector
SUB diffVec, temp, center;

# Compute the texture coordinates
DP3 temp.r, diffVec, state.matrix.modelview.row[0];
DP3 temp.g, diffVec, state.matrix.modelview.row[1];
MUL temp.rg, temp, params2.r;

# Center background image
ADD temp.rg, temp, .5;

# Look up the texel value
TEX temp.rgb, temp, texture[3], 2D;
MOV temp.a, 1.0;

# Blend the background pixel
SUB texblen, 1.0, dst.a;
MAD dst, temp, texblen.x, dst;

# Write the output color
MOV result.color, dst;

END

---