/home/carolina/workspace/spvolren_cpu/volumeShaders/volume_sm3.fp

Vá para a documentação deste arquivo.

!!ARBfp1.0
OPTION NV_fragment_program2;

# Copyright (c) 2005  Institute for Visualization and Interactive
# Systems, University of Stuttgart, Germany
#
# This source code is distributed as part of the single-pass volume
# rendering project. Details about this project can be found on the
# project web page at http://www.vis.uni-stuttgart.de/eng/research/
# fields/current/spvolren. This file may be distributed, modified,
# and used free of charge as long as this copyright notice is
# included in its original form. Commercial use is strictly
# prohibited.
#
# Filename: volume_sm3.fp

#! VOLUME = 0
#! TRANSFERFUNCTION = 1
#! BACKGROUND = 2

# r = step
# g = gradient scale
# b = gradient offset
# a = z-value of background plane
PARAM params = program.local[0];

# r = texture coordinate scale
# g = number of iterations
# b = isovalue of isosurface
PARAM params2 = program.local[1];
PARAM center = program.local[2];
PARAM texMax = program.local[3];

PARAM scaleFactors = program.local[5];

TEMP geomDir;
TEMP geomPos;
TEMP texblen;
TEMP diffVec;
TEMP scalar;
TEMP camera;
TEMP normal;
TEMP temp1;
TEMP temp2;
TEMP temp;
TEMP pos;
TEMP src;
TEMP dst;
TEMP dir;
TEMP tex;

# Compute the ray's starting point
MOV geomPos, fragment.texcoord[0];
MUL pos, geomPos, scaleFactors;
MOV pos.a, 0.0;

# Compute the camera position by translating the origin to the center of the
# volume
MOV camera, state.matrix.modelview.invtrans.row[3];

# Compute the ray direction
SUB geomDir, geomPos, camera;

# Normalize the direction (done manually instead of with NRM to improve
# accuracy)
DP3 geomDir.w, geomDir, geomDir;
RSQ geomDir.w, geomDir.w;
MUL geomDir, geomDir, geomDir.w;
MOV geomDir.w, 0.0;

MUL dir, geomDir, scaleFactors;

# Initialize scalar value
# RGB = gradient, alpha = scalar value
TXL scalar, pos, texture[0], 3D;
MOV scalar.g, scalar.a;
MOV scalar.a, 0.0;

# Initialize destination color
MOV dst, 0.0;

# Move one step forward
MAD pos, dir, params.r, pos;

REP params2.g;
        REP params2.g;

                # Lookup new scalar value
                TXL tex, pos, texture[0], 3D;
                MOV scalar.r, tex.a;

                # Lookup color in pre-int texture
                TXL src, scalar, texture[1], 2D;

                # TODO Early ray termination (no gain of speed so far)
                #SUBC texblen.r, 1.0, dst.a;
                #BRK (LE.x);

                # Perform blending
                SUB texblen.r, 1.0, dst.a;
                MAD_SAT dst, src, texblen.r, dst;

                # Move one step forward
                MAD pos, dir, params.r, pos;

                # Terminate loop if outside volume
                SGE temp1, pos, 0.0;
                SLE temp2, pos, texMax;
                DP3 temp1.r, temp1, temp2;
                SEQC temp1.r, temp1.r, 3.0;
                BRK (EQ.x);

                # Save current scalar value
                MOV scalar.g, scalar.r;

        ENDREP;

        BRK (LE.x);

ENDREP;

# Compute the normal of the background plane (this is just the negative view
# direction which initially is (0, 0, -1))
MOV normal, state.matrix.modelview.row[2];

# Compute the plane constant (we want the plane to be located in the volume
# center)
DP3 temp1.r, normal, center;

# Move the plane behind the volume: d' = <n,(x - l n)> = <n, x> - l <n, n>;
# l = 0.71 is chosen since it is greater than half the cube diagonal 
DP3 temp1.g, normal, normal;
MAD temp1.r, temp1.g, -.71, temp1.r;

# Compute ray parameter
DP3 temp1.g, normal, geomPos;
SUB temp1.g, temp1.r, temp1.g;
DP3 temp1.b, normal, geomDir;
DIV temp.r, temp1.g, temp1.b;

# Compute ray/plane intersection
MAD temp.rgb, temp.r, geomDir, geomPos;

# Compute the difference vector
SUB diffVec, temp, center;

# Compute the texture coordinates
DP3 temp.r, diffVec, state.matrix.modelview.row[0];
DP3 temp.g, diffVec, state.matrix.modelview.row[1];
MUL temp.rg, temp, params2.r;

# Center background image
ADD temp.rg, temp, .5;

# Look up the texel value
TEX temp.rgb, temp, texture[2], 2D;
MOV temp.a, 1.0;

# Blend the background pixel
SUB texblen, 1.0, dst.a;
MAD dst, temp, texblen.x, dst;

# Write the output color
MOV result.color, dst;

END

---